マウスの動きを自由にカスタマイズするためのFR-Script解説

マウスの動きをスクリプト指定で制御するための機能です。

設定ダイアログのマウスの揺らし方の選択肢で「スクリプト指定でカスタマイズする」を選ぶと、選択肢の右下の「マウス動作カスタマイズ(FR-Script)」ボタンが押下可能になります。ボタンを押下すると、スクリプトを入力できるダイアログボックスが開くので、スクリプトを入力してOKボタンを押して下さい。

設定ダイアログを開く前から「スクリプト指定でカスタマイズする」の状態になっていれば、このタイミングで、マウスを揺らす時間間隔で指定した秒数が経過後にスクリプトの実行が始まります。

そうでない場合は、設定ダイアログをOKボタンで閉じたタイミングから、マウスを揺らす時間間隔で指定した秒数が経過後にスクリプトの実行が始まります。

基本的には、マウスを揺らす時間間隔で指定した秒数が経過するごとにスクリプトが先頭から呼び出されますが、前回のスクリプト実行が終了していない場合は、そのまま処理が継続されます。そのため、スクリプトの中でループ制御とSleepを駆使して独自の間隔でマウス制御を行うことも可能です。

なお、スクリプトが無限ループするなどして完了しない場合、スクリプトの書き換えを行ってOKボタンを押した場合や、マウスの揺らし方を変えたタイミングで、スクリプトの中断指示が送信されます。マウスふるふる自体が終了した場合は、スクリプトを実行しているスレッドを強制終了します。

文法ルールは、「いじくるつくーる」に搭載されていたR-Scriptと似たようなものとなっており、軽量版です(FR-ScriptのFはFeatherの略です)。詳細な文法解説は後述します。

■ボタンの解説
・・・ テキストファイルとしてファイルを開き、このダイアログに取り込みます。エクスプローラからドラッグ＆ドロップすることもできます。
・・・ 入力されている内容をテキストファイルとして保存します。文字コードはUTF-8(BOM付き)固定です。

スクリプトのサンプル

以下に、FR-Scriptのサンプルを示しますので、これを参考に独自の動きを構築してみてください。

(1) 指定秒数ごとに、現在のマウスの位置から、左上に100ピクセルずつずらし続ける

組込関数GetCursorPosX(), GetCursorPosY()は、現在のマウスカーソルの座標(x, y)をそれぞれ返します。組込関数SetCursorPos(x, y)は、マウスカーソルの位置を座標(x, y)に設定します。

x = GetCursorPosX()
y = GetCursorPosY()
SetCursorPos(x-100, y-100)

(2) 指定秒数ごとに、左右にマウスを動かすが、動かす距離（ミッキー単位）はランダム

組込関数MoveMouse(dx, dy)は、マウスカーソルを右にdx、下にdy移動させます（ミッキー単位）。左・上に移動したい場合は、負の値を指定します。

srand(GetCurrentSecond())
r = rand()
MoveMouse(r, 0)
MoveMouse(-r, 0)

(3) 指定秒数は無視して、0.1秒(100ミリ秒)ごとに、マウスを右上(10ミッキー)に動かし、すぐに左下(10ミッキー)に動かす

while(true) {
    MoveMouse(10, -10)
    MoveMouse(-10, 10)
    Sleep(100)
}

(4) 指定秒数ごとに、マウスホイールを-128だけは動かす

組込関数MouseWheel(n)は、マウスホイールをnだけ回転させたことにします。

MouseWheel(-128)

(5) 指定秒数ごとに、マウスの左ボタン・右ボタン・中央ボタン（ホイールの押し込み）を同時に押し(1)・離し(0)する

組込関数MouseButtonLeft(p), MouseButtonRight(p), MouseButtonMiddle(p) は、それぞれマウスの左ボタン・右ボタン・中央ボタンが、p=1押し、p=0離し したことにします。

MouseButtonLeft(1)
MouseButtonRight(1)
MouseButtonMiddle(1)
MouseButtonLeft(0)
MouseButtonRight(0)
MouseButtonMiddle(0)

(6) 指定秒数ごとに、マウスのX1ボタン・X2ボタン（ブラウザの進む・戻るが割り当てられることの多いボタン）を同時に押し(1)・離し(0)する

組込関数MouseButtonX1(p), MouseButtonX2(p) は、それぞれマウスのX1・X2が、p=1押し、p=0離し したことにします。

MouseButtonX1(1)
MouseButtonX1(0)
MouseButtonX2(1)
MouseButtonX2(0)

(7) 指定秒数ごとに、Scrool LockキーのトグルON・トグルOFFを繰り返す (標準機能では、トグルON⇔OFFが瞬間的に行われて元に戻るが、このスクリプトでは、ONで待ち、OFFで待ち、ONで待ち、OFFで待ち、…といった動きになる)

なお、組込関数KeybdEvent(keycode, p)の第1引数keycodeはキーコード、第2引数pは押し(1)・離し(0)を意味しています。

KeybdEvent(0x91, 1)
KeybdEvent(0x91, 0)

// 次の書き方もできます
KeybdEvent(VK_SCROLL, 1)
KeybdEvent(VK_SCROLL, 0)

(8) 指定秒数ごとに、「管」の文字を入力します

なお、組込関数SendInputUnicode(c, p)の第1引数cは入力したい文字（1文字だけ指定）、第2引数pは押し(1)・離し(0)を意味しています。

SendInputUnicode("管", 1)
SendInputUnicode("管", 0)

(9) 指定秒数は無視して、0.1秒(100ミリ秒)ごとに、マウスを右上(16ミッキー)に動かし、2秒待ち、左下(16ミッキー)に動かし、2秒待ち、…を繰り返す

loop {
    MoveMouse(-0x10, 0x10)
    Sleep(2000)
    MoveMouse(0x10, -0x10)
    Sleep(2000)
}

(10) 指定秒数ごとに、ダイアログを表示する

TextOut("サンプルダイアログ", "タイトル")

ダイアログを閉じるまでは、スクリプト実行中の扱いとなり、指定秒数後の次のターンでのダイアログの表示は行われませんが、スクリプトの実行は別スレッドにて並行で実行されているため、ダイアログを閉じてから指定秒数へのカウントが行われるのではなく、ダイアログが開いている間も指定秒数へのカウントは行われます。

FR-Script スクリプト仕様

FR-Scriptは、数値と文字列を直感的に扱える軽量なスクリプト言語です。コールバック(CB)を利用して、スクリプト実装元のプログラム機能を呼び出す他、時刻取得・乱数の取得・Windows APIを利用したダイアログ表示や環境変数操作にも対応しています。

1. 基本仕様

・変数とデータ型

変数名および後述の関数名は、アンダーバー(_)またはアルファベットで始まり、数字・アンダーバー(_)・アルファベットが続くというルールで付けます。下位互換性のために最後に$を付けることもできますが、現在では特に意味を持ちません。英大文字・小文字を区別しません。特に宣言などは必要なく使用できます。すべての変数はグローバル変数となります。

代入可能な型は、数値、文字列、およびこれらの配列です。配列の添え字は[n]で表します。nは0以上の数値です。変数の初期値は0となります。

配列は、x[n] = p の形で代入を行うことで、代入と共に、0 〜 n を添字が使える配列が準備されます。

初期代入変数としてTRUE=1, ISNT=1, YES=1, MAXINTEGER=2147483647, MININTEGER=-2147483648, VK_***(仮想キーコードの各値) があります。英大文字・小文字は区別されません。これらと同じ名前の変数に代入しようとすると、代入した値が優先されます。

CB、制御文で使用するキーワードなどは、変数名としては使用できません。

・即値

　基本的に数値は10進数で指定します。32bitで表現可能な範囲(MININTEGER 〜 MAXINTEGER)を扱えます。0xで始まると16進数、0bで始まると2進数が指定できます。

・文字列リテラル

　ダブルコーテーション "..." またはシングルコーテーション '...' で囲みます。

• エスケープシーケンス: \n(改行), \t(タブ), \\, \" などが利用可能です。
• RAW文字列: @ を頭に付けると、\ をそのまま文字として扱います。
  例: @"C:\Users\Documents" （Windowsのパス指定に便利です）

　スクリプトの処理系は、外部とのやり取りには文字コードにUTF-16LEを用いますが、内部的には文字コードにUTF-8を用います。

・コメント

　#, //, ; で始まる行は、行末までコメント（何も行わない）となります。

2. 演算子

計算結果がオーバーフローしてもエラーにはなりません。

3. 制御構造 (IF-ELSE, WHILE, FOR, REPEAT-UNTIL, EXIT)

条件分岐は IF - ELSE IF - ELSE を使用します。
IFの後ろの式が真の場合は直後のブロックを実行し、偽の場合はELSE IFの式を評価し、…、いずれの条件も真にならなかった場合はELSEの後ろのブロックを実行します。ELSE IF, ELSEのブロックは省略可能です。

if (score >= 80) {
    msg = "合格！"
}
else {
    msg = "がんばりましょう"
}

繰り返しは WHILE を使用します。WHILEの後ろの式が真の状態の場合に、後ろのブロック内を実行します。ブロックの最後まで実行すると、再び式の評価が再び行われ、…、とループします。WHILE(TRUE)と書くと無限ループになりますが、WHILE(TRUE) の特別な書き方として LOOPという書き方も可能です。

// i=0〜9の間ループする
i = 0
while(i < 10) {
    TextOut("" + i)
    ++i
}

// 無限ループになります
i = 0
loop {
    TextOut("" + i)
    ++i
}

繰り返しは FOR を使用することもできます。FOR (式1 , 式2 , 式3)の形になります。最初に「式1」が評価（変数初期化を想定）され、式2が真の状態の場合に、後ろのブロック内を実行します。ブロックの最後まで実行すると、式3(変数のインクリメントを想定)が評価され、再び式2の評価が再び行われ評価結果が真ならば、…、とループします。
なお、式1〜式3は省略することができ、式2を省略すると常に真（無限ループ）となります。

// i=0〜9の間ループする
for(i=0, i<10, ++i) {
    TextOut("" + i)
}

// 無限ループになります
i=0
for(,,) {
    TextOut("" + i)
}

for直後の括弧内の式は、C言語のようなセミコロン区切りではなく、カンマ区切りとなります。

WHILE, LOOP, FOR から抜けるには、式の評価が偽になる場合の他、BREAK を使います。条件評価にすぐに戻る場合は CONTINUE を使います。

i = 0
loop {
    TextOut("" + i)
    ++i
    // 現在時刻の秒の部分が30を超えたらループを抜けます
    if (GetCurrentSecond() > 30) {
        break
    }
}
TextOut("ループを抜けました")

i = 0
while(i < 100) {
    TextOut("" + i)
    // 現在時刻の秒の部分が30未満の時は、++iを実行せずに条件評価まで戻ります
    if (GetCurrentSecond() < 30) {
        continue
    }
    ++i
}

i = 0
while(true) {
    TextOut("" + i)
    // 現在時刻の秒の部分が30を超えたらループを抜け、スクリプト自体も直ちに終了します
    if (GetCurrentSecond() > 30) {
        exit
    }
    ++i
}
TextOut("ここには来ません")

ループ継続判断を後から行う方式として、REPEAT-UNTIL を使用することもできます。まずはブロック内の実行が行われ、その後に行われる式の評価が真ならばループから抜けます。

// i=0〜5の間ループする
i = 0
repeat {
    TextOut("" + i)
    ++i
} until (i == 5)

スクリプトの終端に達するか、EXITが実行されると、スクリプトを終了します。既定では、変数はすべてクリアされて、次回実行時には残りません。必要な場合は後述の DEFINE("KeepVar",1) で変数のクリアが行われないようにするか、setenv(), getenv()を使って環境変数へ退避してください。環境変数は、プログラムの実行中は残ります。

制御文で使われるキーワードは、英大文字・小文字は区別されません。

4. 組込関数リファレンス

4-1. 制御・日時・乱数

4-2. 文字列・変換関数

4-3. 配列

4-4. システム・UI関数

4-5. マウス・キーボードイベント関数

※[...] … 省略可能な引数であることを示します。
組込関数名の英大文字・小文字は区別されません。
下位互換性のため、組込関数名の後ろに$をつけることができますが、現在では単に無視されます。

5. ユーザー定義関数

// ユーザー定義関数
func get_sum(a, b, c) {
    d = a + b + c
    return d
}

// rに6が代入される
r = get_sum(1, 2, 3)

FUNCキーワードから続く一連のブロックでユーザー定義関数を定義できます。関数名の命名ルールは変数名と同じです。英大文字・小文字は区別されません。RETURNで関数から抜けるとともに、結果としての値を返却できます。

関数内で使われる変数であっても、グローバルスコープの扱いとなりますが、引数は、この関数内のみのローカルスコープとなります。

呼び出し時の引数の数と、関数定義時の引数の数が違う場合は、少ない方が有効となります。引数には数値・文字列を指定できます。配列は指定できません。
ユーザー定義関数から、自身または別のユーザー定義関数を呼び出すこともできますが、呼び出しが重ねられる回数は512回に制限されます。それを超えるとエラーになります。

6. サンプルコード

// ユーザーへの挨拶と環境変数の表示
user = getenv("USERNAME")
IF (Question(user + "さん、環境を表示しますか？", "確認")) {
    path = getenv("PATH")
    Information("PATHの内容: " + left(path, 50) + "...", "システム情報")
}

7. その他