スクリプトでキーボードシミュレートを自由にカスタマイズするためのFR-Script解説

キーボードシミュレートするキーや文字列をスクリプト指定で制御するための機能です。

入力モードを選択するラジオボタンで「スクリプト入力モード」を選ぶと、入力した文字列がスクリプト(FR-Script)として扱われ、「入力開始」ボタンの押下でスクリプトが実行されるようになります。

なお、スクリプトが無限ループするなどして完了しない場合、「中止」ボタンを押すと中止できます。本プログラム自体が終了した場合は、スクリプトを実行しているスレッドを強制終了します。
スクリプト入力モードを利用する場合は、「入力を○○回繰り返す」の指定は無視されます。ループ制御はスクリプト内で指定してください。

文法ルールは、「いじくるつくーる」に搭載されていたR-Scriptと似たようなものとなっており、軽量版です(FR-ScriptのFはFeatherの略です)。詳細な文法解説は後述します。

スクリプトのサンプル

以下に、FR-Scriptのサンプルを示しますので、これを参考に独自の動きを構築してみてください。

(1) ランダムな数字を3文字入力する。

　KeybdEvent()は指定された仮想キーコードを押し離しする組込関数であり、第2引数は、キーボードを 1 = 押す、0 = 離す ことのシミュレーションを意味します。
　その他の組込関数は、スクリプト仕様の関数リファレンスをご参照ください。

srand(GetCurrentSecond());
i = rand() % 10
KeybdEvent(VK_0+i, 1)
KeybdEvent(VK_0+i, 0)
Sleep(20)
i = rand() % 10
KeybdEvent(VK_0+i, 1)
KeybdEvent(VK_0+i, 0)
Sleep(20)
i = rand() % 10
KeybdEvent(VK_0+i, 1)
KeybdEvent(VK_0+i, 0)
Sleep(20)

(2) Aを10回押す。

　KeybdEvent()で利用できるキーコードは、仮想キーコードと特殊入力一覧を参照してください。

i = 0
while(i < 10) {
    CB.SetWindowTitle("進捗："+i*10+"% - キーボードシミュレータ")
    KeybdEvent(VK_A, 1)
    KeybdEvent(VK_A, 0)
    Sleep(20)
    ++i
}

for(i=0, i<10, ++i) {
    CB.SetWindowTitle("進捗："+i*10+"% - キーボードシミュレータ")
    KeybdEvent(VK_A, 1)
    KeybdEvent(VK_A, 0)
    Sleep(20)
}

上記のサンプルで使われているコールバック関数 CB.SetWindowTitle(s) は、ウィンドウタイトルをsで指定した文字列に設定します。逆に、ウィンドウタイトルを取得するには、コールバック関数 CB.GetWindowTitle() を使います。

// 現在のウィンドウタイトルをメッセージボックスに表示する
TextOut(CB.GetWindowTitle())

(3) 「管」の文字を10回入力する。

　SendInputUnicode() は、指定された1文字をアクティブなプログラムに流し込む組込関数です。

i = 0
while(i < 10) {
    SendInputUnicode("管", 1)
    SendInputUnicode("管", 0)
    Sleep(20)
    ++i
}

for(i=0, i<10, ++i) {
    SendInputUnicode("管", 1)
    SendInputUnicode("管", 0)
    Sleep(20)
}

FR-Script スクリプト仕様

FR-Scriptは、数値と文字列を直感的に扱える軽量なスクリプト言語です。コールバック(CB)を利用して、スクリプト実装元のプログラム機能を呼び出す他、時刻取得・乱数の取得・Windows APIを利用したダイアログ表示や環境変数操作にも対応しています。

1. 基本仕様

・変数とデータ型

変数名および後述の関数名は、アンダーバー(_)またはアルファベットで始まり、数字・アンダーバー(_)・アルファベットが続くというルールで付けます。下位互換性のために最後に$を付けることもできますが、現在では特に意味を持ちません。英大文字・小文字を区別しません。特に宣言などは必要なく使用できます。すべての変数はグローバル変数となります。

代入可能な型は、数値、文字列、およびこれらの配列です。配列の添え字は[n]で表します。nは0以上の数値です。変数の初期値は0となります。

配列は、x[n] = p の形で代入を行うことで、代入と共に、0 〜 n を添字が使える配列が準備されます。

初期代入変数としてTRUE=1, ISNT=1, YES=1, MAXINTEGER=2147483647, MININTEGER=-2147483648, VK_***(仮想キーコードの各値) があります。英大文字・小文字は区別されません。これらと同じ名前の変数に代入しようとすると、代入した値が優先されます。

CB、制御文で使用するキーワードなどは、変数名としては使用できません。

・即値

　基本的に数値は10進数で指定します。32bitで表現可能な範囲(MININTEGER 〜 MAXINTEGER)を扱えます。0xで始まると16進数、0bで始まると2進数が指定できます。

・文字列リテラル

　ダブルコーテーション "..." またはシングルコーテーション '...' で囲みます。

• エスケープシーケンス: \n(改行), \t(タブ), \\, \" などが利用可能です。
• RAW文字列: @ を頭に付けると、\ をそのまま文字として扱います。
  例: @"C:\Users\Documents" （Windowsのパス指定に便利です）

　スクリプトの処理系は、外部とのやり取りには文字コードにUTF-16LEを用いますが、内部的には文字コードにUTF-8を用います。

・コメント

　#, //, ; で始まる行は、行末までコメント（何も行わない）となります。

2. 演算子

計算結果がオーバーフローしてもエラーにはなりません。

3. 制御構造 (IF-ELSE, WHILE, FOR, REPEAT-UNTIL, EXIT)

条件分岐は IF - ELSE IF - ELSE を使用します。
IFの後ろの式が真の場合は直後のブロックを実行し、偽の場合はELSE IFの式を評価し、…、いずれの条件も真にならなかった場合はELSEの後ろのブロックを実行します。ELSE IF, ELSEのブロックは省略可能です。

if (score >= 80) {
    msg = "合格！"
}
else {
    msg = "がんばりましょう"
}

繰り返しは WHILE を使用します。WHILEの後ろの式が真の状態の場合に、後ろのブロック内を実行します。ブロックの最後まで実行すると、再び式の評価が再び行われ、…、とループします。WHILE(TRUE)と書くと無限ループになりますが、WHILE(TRUE) の特別な書き方として LOOPという書き方も可能です。

// i=0〜9の間ループする
i = 0
while(i < 10) {
    TextOut("" + i)
    ++i
}

// 無限ループになります
i = 0
loop {
    TextOut("" + i)
    ++i
}

繰り返しは FOR を使用することもできます。FOR (式1 , 式2 , 式3)の形になります。最初に「式1」が評価（変数初期化を想定）され、式2が真の状態の場合に、後ろのブロック内を実行します。ブロックの最後まで実行すると、式3(変数のインクリメントを想定)が評価され、再び式2の評価が再び行われ評価結果が真ならば、…、とループします。
なお、式1〜式3は省略することができ、式2を省略すると常に真（無限ループ）となります。

// i=0〜9の間ループする
for(i=0, i<10, ++i) {
    TextOut("" + i)
}

// 無限ループになります
i=0
for(,,) {
    TextOut("" + i)
}

for直後の括弧内の式は、C言語のようなセミコロン区切りではなく、カンマ区切りとなります。

WHILE, LOOP, FOR から抜けるには、式の評価が偽になる場合の他、BREAK を使います。条件評価にすぐに戻る場合は CONTINUE を使います。

i = 0
loop {
    TextOut("" + i)
    ++i
    // 現在時刻の秒の部分が30を超えたらループを抜けます
    if (GetCurrentSecond() > 30) {
        break
    }
}
TextOut("ループを抜けました")

i = 0
while(i < 100) {
    TextOut("" + i)
    // 現在時刻の秒の部分が30未満の時は、++iを実行せずに条件評価まで戻ります
    if (GetCurrentSecond() < 30) {
        continue
    }
    ++i
}

i = 0
while(true) {
    TextOut("" + i)
    // 現在時刻の秒の部分が30を超えたらループを抜け、スクリプト自体も直ちに終了します
    if (GetCurrentSecond() > 30) {
        exit
    }
    ++i
}
TextOut("ここには来ません")

ループ継続判断を後から行う方式として、REPEAT-UNTIL を使用することもできます。まずはブロック内の実行が行われ、その後に行われる式の評価が真ならばループから抜けます。

// i=0〜5の間ループする
i = 0
repeat {
    TextOut("" + i)
    ++i
} until (i == 5)

スクリプトの終端に達するか、EXITが実行されると、スクリプトを終了します。既定では、変数はすべてクリアされて、次回実行時には残りません。必要な場合は後述の DEFINE("KeepVar",1) で変数のクリアが行われないようにするか、setenv(), getenv()を使って環境変数へ退避してください。環境変数は、プログラムの実行中は残ります。

制御文で使われるキーワードは、英大文字・小文字は区別されません。

4. 組込関数リファレンス

4-1. 制御・日時・乱数

4-2. 文字列・変換関数

4-3. 配列

4-4. システム・UI関数

4-5. マウス・キーボードイベント関数

※[...] … 省略可能な引数であることを示します。
組込関数名の英大文字・小文字は区別されません。
下位互換性のため、組込関数名の後ろに$をつけることができますが、現在では単に無視されます。

5. ユーザー定義関数

// ユーザー定義関数
func get_sum(a, b, c) {
    d = a + b + c
    return d
}

// rに6が代入される
r = get_sum(1, 2, 3)

FUNCキーワードから続く一連のブロックでユーザー定義関数を定義できます。関数名の命名ルールは変数名と同じです。英大文字・小文字は区別されません。RETURNで関数から抜けるとともに、結果としての値を返却できます。

関数内で使われる変数であっても、グローバルスコープの扱いとなりますが、引数は、この関数内のみのローカルスコープとなります。

呼び出し時の引数の数と、関数定義時の引数の数が違う場合は、少ない方が有効となります。引数には数値・文字列を指定できます。配列は指定できません。
ユーザー定義関数から、自身または別のユーザー定義関数を呼び出すこともできますが、呼び出しが重ねられる回数は512回に制限されます。それを超えるとエラーになります。

6. サンプルコード

// ユーザーへの挨拶と環境変数の表示
user = getenv("USERNAME")
IF (Question(user + "さん、環境を表示しますか？", "確認")) {
    path = getenv("PATH")
    Information("PATHの内容: " + left(path, 50) + "...", "システム情報")
}

7. その他